Qfyilyi

Let's say I have 2 for each statement with 2 none related table
The first one is

for each table-1 

   disp table-1.col1 

        table-1.col2.

end. 



for each table-2

   disp table-2.col1

        table-2.col2.

end.

and it displays to me like this

table-1.col1 table-1.col2 

table-1.col1 table-1.col2

table-1.col1 table-1.col2



table-2.col1 table-2.col2

table-2.col1 table-2.col2

table-2.col1 table-2.col2

I would like it to display like this

---------- Table 1 ---------      ---------- Table 2 --------

|table-1.col1 table-1.col2 |      |table-2.col1 table-2.col2|      

|table-1.col1 table-1.col2 |      |table-2.col1 table-2.col2|

|table-1.col1 table-1.col2 |      |table-2.col1 table-2.col2|

How to do that ?

Since the tables are unrelated you'll have to do some data manipulation to get the side-by-side chart output you're looking for. You can create a "line" temp table that holds the four fields you want to show across each output line. Go through each of the tables, adding the record data to each line. Then go through the line temp table and output the line data.

DEFINE VARIABLE linecnt AS INTEGER NO-UNDO.



DEFINE TEMP-TABLE ttLine

    FIELD linenum AS INTEGER

    FIELD tbl1col1 AS CHARACTER

    FIELD tbl1col2 AS CHARACTER

    FIELD tbl2col1 AS CHARACTER

    FIELD tbl2col2 AS CHARACTER

    INDEX Idx1 IS PRIMARY linenum.



linecnt = 1.  /* Initialize the line counter. */



/* Go thru table-1, creating a ttLine for each record. */

FOR EACH table-1 NO-LOCK:

    CREATE ttLine.

    ASSIGN

        ttLine.linenum = linecnt

        ttLine.tbl1col1 = table-1.col1 

        ttLine.tbl1col2 = table-1.col2

        linecnt = linecnt + 1.

END. 



linecnt = 1.  /* Reset the line counter. */



/* Go thru table-2, adding data to ttLine and creating new records if necessary. */

FOR EACH table-2 NO-LOCK:

    FIND FIRST ttLine WHERE ttLine.linenum = linecnt NO-ERROR.

    IF NOT AVAILABLE(ttLine) THEN

    DO:

        CREATE ttLine.

        ttLine.linenum = linecnt.

    END.



    ASSIGN

        ttLine.tbl2col1 = table-2.col1

        ttLine.tbl2col2 = table-2.col2

        linecnt = linecnt + 1.

END.



/* Go thru ttLine, output data. */

OUTPUT TO VALUE("output.txt").



PUT UNFORMATTED

    "---------- Table 1 ---------      ---------- Table 2 --------"

    SKIP.



FOR EACH ttLine:

    PUT UNFORMATTED

        "|" + 

        STRING(ttLine.tbl1col1, "X(12)") + " " + STRING(ttLine.tbl1col2, "X(12)") + 

        " |      |" +

        STRING(ttLine.tbl2col1, "X(12)")  + " " + STRING(ttLine.tbl2col2, "X(12)") + 

        "|" 

        SKIP.

END.



OUTPUT CLOSE.

The above example should give you the output you're looking for. It will also handle situations where you don't have the same number of records in each table. It will leave blank spaces where there is no data.

If you specify the width and col(umn) for the two frames, you can control that they should be displayed next to each other.

for each Salesrep:                                                                      

   display salesrep.salesrep                                                            

           salesrep.repname                                                             

       with down frame frm-salesrep                                                     

       width 40.                                                                        

end.                                                                                    



for each Item:                                                                          

    display item.ItemNum                                                                

            item.ItemName                                                               

       with down frame frm-item                                                         

       col 41.                                                                                    

end.